import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
	kotlin("jvm") version "1.9.0"
	application
}

group = "gay.pizza"
version = "1.0-SNAPSHOT"

repositories {
	mavenCentral()
}

dependencies {
	implementation(kotlin("stdlib"))
	val gdxVersion: String by rootProject
	val ktxVersion: String by rootProject
	val gdxControllersVersion: String by rootProject
	val hsluvVersion: String by rootProject
	implementation("com.badlogicgames.gdx:gdx:$gdxVersion")
	implementation("com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion")
	implementation("com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop")
	implementation("com.badlogicgames.gdx:gdx-freetype:$gdxVersion")
	implementation("com.badlogicgames.gdx:gdx-freetype-platform:$gdxVersion:natives-desktop")
	implementation("com.badlogicgames.gdx-controllers:gdx-controllers-core:$gdxControllersVersion")
	implementation("com.badlogicgames.gdx-controllers:gdx-controllers-desktop:$gdxControllersVersion")
	implementation("io.github.libktx:ktx-math:$ktxVersion")
	implementation("org.hsluv:hsluv:$hsluvVersion")
}

tasks.withType<KotlinCompile> {
	val kotlinOptionsJvmTarget: String by rootProject
	kotlinOptions.jvmTarget = kotlinOptionsJvmTarget
}

java {
	val javaVersionCompatibility: String by rootProject
	sourceCompatibility = JavaVersion.toVersion(javaVersionCompatibility)
	targetCompatibility = JavaVersion.toVersion(javaVersionCompatibility)
}

application {
	mainClass.set("gay.pizza.CavesOfJolk.Program")
	if (System.getProperty("os.name") == "Mac OS X")
		applicationDefaultJvmArgs = listOf("-XstartOnFirstThread") // Make MacOS happy
}
